————————————————————
CCI 指标：
commodity channel index， 中文简称顺势指标
————————————————————
按照波浪理论的原理，股价以5波的方式前进。而发展到最后第5波阶段时，
无论处于上涨波或下跌波，都是行情波动最凶、最猛的时候，群众毫无理性的疯狂，股价在很短的时间内，加速度完成最大幅度的波动。
有些股民想在最安全的范围内买卖股票。但是对于部分冒险性、赌性较高的股民而言，
他们宁可选择在高风险的环境下，介入速度快、利润大的市场。这种市场经常是一翻两瞪眼，下赌注要快，逃得也要快！
可以让人赌得痛快淋漓，给赌性坚强的股民一种快刀斩乱麻的畅快感。
CCI指标就是专门针对极端情况设计的，
首先在+100到—100之间的震荡区，该指标基本上没有意义，不能够对大盘及个股的操作提供多少明确的建议，
当CCI扫描到异常股价波动时，>+100, <-100, 战斗机立刻升空做战，而且立求速战速决，胜负瞬间立即分晓，赌输了也必须立刻加速逃逸！
CCI 用到了平均偏差的概念， 先来理解一下平均偏差（average deviation)
平均偏差(average deviation)
顾名字义：平均偏差就是偏差值求平均吗。 小学算术即可。
偏差值：(deviation)
偏差值是该值和真值之间的差。
真值是多少？ 真值就是这几个值的平均值。
打个比方， 来了一批货物，我们称一下重量，为w1,w1,…wn.
这批货物重量一致性怎么样呢？ 我们先算一下重量的平均值 (w1+w1+…+wn)/n = mw， 这个就是标准值，真值。
再来计算一下每一个货物与均值的差,重还是轻就不管了，反正就是偏差： |w1-mw|, |w1-mw|,…|wn-w|
把差值平均一下就知道这批货物的平均重量偏差了。 (|w1-mw|+|w2-mw|+… +|wn-mw|)/n = AVEDEV(w,n);
平均偏差，反应了数据的离散程度。
然后你就可以对生产厂家说， 看看你们的这批货物质量控制太差了， 平均偏差是xxx.
或者说你们的这批货物质量（重量）控制的太好了，平均偏差是个0 （理想值）， 所有重量都一样。
CCI 指标就是今天的偏差，与 N 天的平均偏差之间的比值。 （没想到数学知识在这里用到了）
今天的偏差大，n 天的偏差小， CCI 值就变大。 反之变小。
今天的值相对于均值大，则取正值，小，则取负值。
AVEDEV: 平均偏差。 average deviation
AVEDEV(TYP,N) 是N天内TYP值的平均偏差。
CCI 计算值采用最高值，最低值，收盘值的平均来计算。 N 值默认为14.
————————————————————
下面为CCI公式：
TYP:=(HIGH+LOW+CLOSE)/3;
CCI:(TYP-MA(TYP,N))/(0.015*AVEDEV(TYP,N));
————————————————————
对CCI 的通俗理解及cci 背离的原因。
标准CCI可简单理解为今天的偏离值跟14天偏离值的比值。系数 1/0.015=66.666
通常情况: 股价长,cci 长， 股价跌，cci 跌。为什么呢？ 我们假定AVEDEV(TYP,N)
是一个相对比较稳定的值。今天股价长了，与均值偏离大了，所以cci 就大了。
今天股价跌了，与均值偏离小了，所以cci 就小了。 （负值的情况也可以同样理解）
也有背离的情况：
股价长了，cci 反而跌了。为什么呢？
这说明，今天偏差并没有增加或者偏差比n天的均偏差并没有增加。
————————————————————
顶背离
————————————————————
CCI指标出现顶背离是指股价在进入拉升过程中，先创出一个高点，CCI指标也相应在﹢100线以上创出新的高点，
之后，股价出现一定幅度的回落调整，CCI曲线也随着股价回落走势出现调整。
但是，如果股价再度向上并超越前期高点创出新的高点时，而CCI曲线随着股价上扬也反身向上但没有冲过前期高点就开始回落，
这就形成CCI指标的顶背离。CCI指标出现顶背离后，股价见顶回落的可能性较大，是比较强烈的卖出信号。
————————————————————
底背离
————————————————————
CCI的底背离一般是出现在远离﹣100线以下的低位区。当K线图上的股价一路下跌，形成一波比一波低的走势，
而CCI曲线在低位却率先止跌企稳，并形成一底比一底高的走势，这就是底背离。
底背离现象一般预示着股价短期内可能将反弹，短期可轻仓跟入
————————————————————
附送一个扩展CCI 公式， 叫CCI_E 吧。
————————————————————
TYP:=(HIGH+LOW+CLOSE)/3;
CCI:(TYP-MA(TYP,14))/(0.015*AVEDEV(TYP,14)),COLORRED,LINETHICK1;
STICKLINE(CCI>REF(CCI,1),HHV(CCI,3),LLV(CCI,3),0,0),COLORYELLOW;
STICKLINE(CCI<REF(CCI,1),HHV(CCI,3),LLV(CCI,3),0,0),COLORBLUE;
DRAWTEXT(((LLV(LOW,21) = LOW) AND NOT((LLV(CCI,21) =CCI))),LLV(CCI,21),'▲'),COLORRED;
DRAWTEXT(((HHV(HIGH,34) = HIGH) AND (MA(CCI,3)<REF(MA(CCI,3),1) OR CCI<REF(CCI,1)) AND NOT((HHV(CCI,34) = CCI))),HHV(CCI,55),'▼'),COLORGREEN;
D_100:100.0,COLOR808080;
D_0:0.0,COLOR808080;
D__100:-100.0,COLOR808080;
仅供参考， 不要据此操作。
因为价格的涨跌是由资金操作的，并不受公式的约束。
指标只是用来做事后统计。当然也可以用来预测，准确率只有天知道了。
再附一个CCI 扩展公式，叫CCI_!_15I
N:=14;
M:=210;
TYP:=(HIGH+LOW+CLOSE)/3;
CCI:(TYP-MA(TYP,N))/(0.015*AVEDEV(TYP,N));
TYP15:=(HHV(HIGH,15)+LLV(LOW,15)+CLOSE)/3;
CCI15:(TYP15-MA(TYP15,M))/(0.015*AVEDEV(TYP15,M)),COLORRED;
AA:=REF(CCI,3)=HHV(CCI,2*3+1);
BB:=BACKSET(AA,3+1);
CC:=FILTER(BB,3) AND CCI=HHV(CCI,3+1);
A1:=BARSLAST(REF(CC,1));
顶背离:=REF(CLOSE,A1+1)<CLOSE AND REF(CCI,A1+1)>CCI AND CC;
DRAWLINE(CC,CCI,FILTER(顶背离>0,5),CCI,0),COLORRED,LINETHICK3;
AA2:=REF(CCI,3)=LLV(CCI,2*3+1);
BB2:=BACKSET(AA2,3+1);
CC2:=FILTER(BB2,3) AND CCI=LLV(CCI,3+1);
AA2A:=BARSLAST(REF(CC2,1));
底背离:=REF(C,AA2A+1)>CLOSE AND REF(CCI,AA2A+1)<CCI AND CC2;
DRAWLINE(CC2,CCI,FILTER(底背离>0,5),CCI,0),COLORRED,LINETHICK4;
DRAWLINE(CC2,CCI,FILTER(底背离>0,5),CCI,0),COLORRED,LINETHICK4;
M100:100, COLOR808080 ;
M_100:-100, COLOR808080;
顶背离，底背离，不要据此操作，这个是不准的。 仅是爱好技术。
吧CCI 与 15倍CCI 放在一起，思路是很好的。